
INTRODUCTION

I gave a version of this paper several years ago before I had started using Version 9 and the world has changed a lot since then. Additionally, Microsoft has introduced Office 2007 which is not compatible with much of the tools offered in SAS versions prior to 9.2. Hence, there is a lot to talk about and the intent here is to introduce as many topics as possible and offer links to further information for some of these. 

SAS offers a number of methods to  communicate with Microsoft Office products. Some are limited in the number of file types or products that they may link to; some are simpler to use than others; some offer little control over the appearance of the final MS file while others give the user a lot of control over the MS file. This paper deals mainly with EXCEL and Word and has notes on other products. The primary focus is on the use of Dynamic Data Exchange (DDE). DDE is especially useful for situations that require a lot of interaction with the MS product and which need to be automated.  The intent is to give a brief overview of these various methods and to offer references for anyone needing further information.

AVAILABLE METHODS (OTHER THAN CUTTING AND PASTING)

Microsoft Libname Engines
SAS PROC IMPORT and EXPORT

ODBC

ODS

DDE

Microsoft Office Plug In
Third Party Software

Microsoft Products Libname Engines 
Here, I will focus on EXCEL

This is a new feature introduced with V9.0 and, to my thinking, is the easiest approach to reading an EXCEL worksheet.  BUT, Office 2007 has a new file structure and the engines that SAS 9.1.3 and 9.2 Phase 1 use to communicate with EXCEL will not work with Office 2007.  SAS 9.2 Phase 2 will work with Office 2007. The site
http://support.sas.com/kb/32/455.html
offers some solutions for dealing with the Office 2007 issue. 

The EXCEL Libname approach is worthy of a whole paper such as

http://www2.sas.com/proceedings/sugi31/024-31.pdf
but to offer a short example, consider:

Libname Infile ‘C:\My Excel Workbook.XLS’;

Data A;

      Set infile.’My Sheet Name’N;

Run;

First, note that the path in the Libname statement is complete and contains the full name of the file and does not simply point to a folder. Next, ’My Sheet Name’N;  is called a Name Literal and here is the name of the sheet that we want to read. If we want to read a named range, you will need to insert a $ before the right hand quotation mark. 
One really neat aspect of this approach is that the Excel worksheet is a SAS dataset as far as the user is concerned. When we issue the Libname statement, the Libref appears in folder Active Libraries of the Explorer window of the session and there is a small blue globe on the icon which indicates that it is an office file (Access files may also be accessed in this manner). If we click on the icon, it opens and we see any worksheets. We can open the worksheet or view columns or do any of the other features offered in the explorer window. 

Note: From the testing that I have done, if you are still running Office 2003 and have installed the Microsoft  Office Compatibility Pack (the url is too long to put here but it can be readily found online)  , SAS 9.1.3 will be able to open an Office 2007 workbook AS LONG AS THE FILE IS SMALL ENOUGH FOR 2003. 

One small gotcha that I have encountered: you need to take an extra step if the spread sheet has an EXCEL TIME value. 

set test.'test$'n (sasdatefmt=( time ='time8.'));
I am not aware of there being a way to use a Libname to write to a Word table.
SAS IMPORT/EXPORT PROCS

These are part of the SAS/ACCESS to PC file formats software and can be used either with raw code or run from desktop wizards. The latter is useful if one doesn’t use the PROCs often enough to recall the syntax. Moreover, the wizard is able to generate the underlying SAS code and this code may be saved and reused in SAS programs.

A simple PROC EXPORT case could be:

PROC EXPORT DATA= WORK.a

            OUTFILE= "D:\My file.xls"

            DBMS=EXCEL2000 REPLACE;

RUN;

PROC EXPORT will write both EXCEL and ACCESS files.

PROC  IMPORT has very similar syntax and will read from EXCEL  and ACCESS.  
ODBC

ODBC is used by PROC SQL to read and write with ACCESS and EXCEL. A quick example could be

PROC SQL; CONNECT TO ODBC (DSN=XXXXXXXXX USER=SAS PW=********); 

CREATE TABLE &SASDB..CUSTOMERS AS SELECT * FROM CONNECTION TO ODBC (SELECT * FROM CUSTOMER); 

Etc.

DISCONNECT FROM ODBC; 

I do not do SQL so I have never tried this approach. However, if you understand SQL, it may be appropriate for you.

Also, ODBC can work with Office 2007 files. See

http://support.sas.com/kb/32/455.html
Enterprise Guide will not directly work with Office 2007 but the url

http://support.sas.com/kb/32/455.html
shows how it can open them using ODBC. 
ODS

ODS offers at least three options for creating files available to EXCEL or Word: CSV and HTML files for EXCEL and RTF for Word (and there are probably more since I last did this paper).

EXCEL will open a CSV file but has to go through an import wizard step. The resulting file will most likely be a simple EXCEL table of the data.  With a slight bit of trickery, EXCEL will open an HTML  file seamlessly. The secret is to use the simple trick of naming the HTML output file with an XLS extension. When EXCEL opens this file, it appears as a normal XLS file. Phil Mason of the UK is supposed to be the author of this trick. 

SAS continues to upgrade ODS so it should become even more important as a means of integrating SAS with MS in future releases.

Also, note that if one is on a non-windows system, one may write out a comma separated file using ODS, say with a Proc Print, and then open this file with windows after it is moved. However, I have found on the mainframe that an ODS/Proc Print combination takes noticeably longer to run than a simple Proc Print. 
DDE

So far, we have seen methods that will read and or write to files that MS products can read but these have not offered a means of controlling the MS products themselves.  The advantage of the previous methods is that they are fairly simple (with ODS being the most powerful and complex). The disadvantage is that the user is limited in the amount of control that they have. Direct Data Exchange (DDE) is a much more powerful tool but has the downside of having a definite learning curve if one is to really take control of the situation. This is due in part to the fact that one can invoke the many EXCEL v4 and Word macros and these can take a while to learn.  Vyverman, SUGI 27, describes how to download information on these macros. 

DDE is a Windows and OS/2 feature that allows various software products that are simultaneously loaded to exchange data in a client/server fashion. The degree to which works appears to depend on the individual software and the effort that the authors have expended in implementing  this feature in their code. SAS only functions in the client role.  The SAS Technical Support document TS325 covers the use of  DDE with SAS and a number of other software products from MS and other manufacturers and is a good resource for a broad introduction to the subject, especially for non-Microsoft products.

DDE is used primarily with EXCEL and ACCESS although there are opportunities to use it with Word. I will discuss EXCEL and Word applications.

I do not routinely write complex EXCEL and Word files so I have little direct experience there. However, I have found DDE to be very useful in reading data from complex spreadsheets. There are a number of examples on SAS/L of coders who need to write data to spreadsheets and control the appearance of the output (e.g., font).  Moreover, one may use DDE to interface with Access, Word and supposedly PowerPoint (but I do not have any examples of the latter).

Again, to use DDE, one must launch both SAS and the MS product and open the MS target file.

The central syntactical issue to using DDE is the identification of the location of the desired MS target.  In order to communicate with the other product at a system level, one uses a DDE Doublet such as

FILENAME fileref DDE ‘EXEL| SYSTEM’ ;

The doublet name derives from the name of the SERVER APP, in this case, EXCEL, and then so-called ITEM, in this case SYSTEM. Doublets are used when telling EXCEL such commands as shut down.

The  triplet is similar to

FILENAME GETDATA DDE "EXCEL|cond001!R5C2:R32C15";

Again, EXEL is the SERVER APP and R5C2:R32C15 is the ITEM. We have added the TOPIC, COND001 which happens to be the sheetname in our workbook.  R5C2 is the starting row and column, and R32C15 is the ending row and column to be read or written to.

A simple job for reading via DDE is
DM 'OUTPUT;CLEAR;LOG;CLEAR;PGM;';

 OPTIONS NOXWAIT NOXSYNC MPRINT;  * note the noxwait and noxsync!!;
DATA _NULL_ ;         

x " 'C:\Program Files\Microsoft Office\Office\EXCEL.EXE'

   ""c:\park\97jun.XLS"" ";

RUN;

DATA _NULL_;

 X=SLEEP(5); * PAUSE SAS PROCESSING FOR 5 SECONDS WHILE EXCEL OPENS AND LOADS THE SHEET;

DATA a;

FILENAME GETDATA DDE "EXCEL|cond001!R5C2:R32C15"; * note the rows and columns. cond1 is the worksheet;

 *the portion after the | is the DDE triplit;

INFILE GETDATA DLM='09'X NOTAB DSD MISSOVER; 

* note the dlm. this separates Excel fields;

INFORMAT COL1 -COL11 $20.;

INPUT COL1-COL11;

DATA _NULL_;** SHUT DOWN EXCEL;

FILENAME CMDS DDE 'EXCEL|SYSTEM';

FILE CMDS;

   PUT '[QUIT()]';

RUN;
In addition to the DDE triplet, note the following items:

1. The options statement included NOXWAIT and NOXSYNC. These allow the X command to be run without opening and closing a DOS window.

2. I launch EXCEL via an X command and open the spreadsheet at the same time. I could have launched EXCEL manually. You will see other ways of doing this on SAS/L.

3. The INFILE statement includes DLM=’09’X and NOTAB and DSD options. ‘09’x is the hex character that separates EXCEL cells. NOTAB is used with DDE to indicate that nontab character delimiters will be used between variables; DSD alters SAS handling of delimiters and tells SAS to treat two adjacent delimiters as indicating a missing value. 

4. Although I did not use one here, one will need an LRECL statement on the infile statement if the EXCEL line is more than 256 bytes. 

A more advanced topic would be having SAS query a workbook, find the sheets contained therein, and then feed these sheetnames to a series of triplets so that SAS could read each of the sheets. An EXCEL workbook, just like a SAS data set, contains metadata that are hidden from the user and which direct the respective systems in accessing their data. With DDE, one may access the hidden EXCEL workbook descriptor file, identify the contents (meaning the names of the spreadsheets) and then automate SAS interaction with the workbook. See the Vyverman, SUGI 27 for a detailed sample.

One extremely important and useful tool for automating applications is the use of EXCEL 4 macros or Word macros to manipulate a spreadsheet or a doc. Visual Basic commands cannot be issued from a SAS session but SAS can invoke VB macros that are embedded in a sheet or doc. The downside to using embedded macros is that either the user will have do deal with the popup box that warns about the macros or one has to turn off the box. The programmer has do balance the risk of suppressing an otherwise important warning with the hassle of dealing with it.  Viergever and Vyverman, SUGI 28, offer an excellent paper on the use of DDE and Word. Both of the authors also have a number of postings in the SAS/L archives that show the use of EXCEL macros from within SAS. Some of Vyverman’s most recent postings appear under the nickname KiloVolt. Unfortunately for the SAS/L community, he now works for SAS Institute and cannot post directly to the list. 

An interesting short example of writing to Word appeared in a recent SAS/L posting. Here, Quentin McMullin places a SAS graph in a Word doc and sizes the output. The fragmentary code is

      PUT '[InsertPicture .Name = "' "&inPath\&file" '"]';

      PUT '[CharLeft 1,1]';  *select graph to format;

      PUT '[FormatPicture .ScaleX = "235%", .ScaleY = "235%"]';

      PUT '[CharRight 1,0]'; *unselect and move pointer over;

In addition to writing a Word doc with SAS, one may also sometimes read data stored in a Word table. The example in the appendix came from Vyverman. I should note that I have found that if I attempt to read a blank Word table, SAS disappears in “puff of smoke” meaning that the SAS shuts down completely on its own accord when it encounters this situation. 

POWERPOINT

I have never seen an example of anyone reading a PowerPoint file and queries about doing this on SAS/L have gone unanswered. However, in SUGI 28, Rick Allen of Citicapital gave an example that involved sending SAS output to EXCEL and linking those data to a PowerPoint file.

Microsoft Office Plugin
This product appeared either late in the V8 cycle or with V9. It basically allows a SAS data set to be linked to a spreadsheet so that a change in one of them will cause the other one to be updated. I have no experience with this product. This product will work with EXCELL and Word.
Third Party Software

There may be more of these available but Allan Churchill has a free utility called Savicells which is a replacement for Procs Import and Export and allows much more granular control on the data being moved. It is offered “as is” and may be downloaded free from 
http://www.sascommunity.org/wiki/File:SaviCells.zip
His firms address is:

http://utilities.savian.net

Summary

There are a number of ways of having SAS read from or write to Microsoft products; the choice depends in part on the complexity of the desired output and on the user’s skill set. New developments in V. 9 have simplifed the data step interface with EXCEL but DDE may still be the only means of writing to Word files. ODS development continues and more file formats are being offered. Some of these may be important in the future. And, if you should have documentation on EXCEL V4 macros, guard it well.

 APPENDIX

Writing to a Word Document and reading from it. Koen Vyverman posted this as an example of reading from a Word table but it nicely illustrates both sides of the I/O issue.

  %* Start MS Word, and define a DDE doublet-style filename         *;
  %* WORDSYS through which to send WordBasic commands.              *;
  options noxsync noxwait xmin;

  filename wordsys dde 'winword|system' lrecl=5000;

  data _null_;

    length fid rc start stop time 8;

    fid=fopen('wordsys','s');

    if (fid le 0) then do;

      rc=system('start winword');

      start=datetime();

      stop=start+10;

      do while (fid le 0);

        fid=fopen('wordsys','s');

        time=datetime();

        if (time ge stop) then fid=1;

        end;

      end;

    rc=fclose(fid);

  run;

  %* Minimize the Word application.                                 *;
  data _null_;

    file wordsys;

    put '[AppMinimize]';

  run;

  %* Set the default directory and get a new blank document.        *;
  data _null_;

    file wordsys;

    put '[ChDefaultDir "c:\temp",0]';

    put '[FileNewDefault]';

  run;

  %* For demonstration purposes the following creates a Word        *;
  %* document with a small table inside, saves and closes it.       *;
  data _null_;

    file wordsys;

    put '[Insert "There is a table here somewhere..."]';

    put '[InsertPara]';

    put '[InsertPara]';

    put '[Insert "Product"+Chr$(9)+"Date"+Chr$(9)+"Amount"]';

    put '[InsertPara]';

    put '[Insert "Eek"+Chr$(9)+"12-Apr-2002"+Chr$(9)+"4566.99"]';

    put '[InsertPara]';

    put '[Insert "A"+Chr$(9)+"23-May-2002"+Chr$(9)+"-34.25"]';

    put '[InsertPara]';

    put '[Insert "Mouse"+Chr$(9)+"01-Jul-2002"+Chr$(9)+"35.00"]';

    put '[InsertPara]';

    put '[ParaUp 4,1]';

    put '[TextToTable.ConvertFrom="1",.NumColumns="3",.NumRows="4",'
        ' .InitialColWidth="Auto",.Format="9",.Apply="63"]';

    put '[StartOfDocument(0)]';

    put '[FileSaveAs.Name="Document with a Table"]';

    put '[FileClose 2]';

  run;

  %* Now we can start. First open the document we wish to extract   *;
  %* table data from.                                               *;
  data _null_;

    file wordsys;

    put '[FileOpen.Name="Document with a Table"]';

  run;

  %* Then locate the table and select it.                           *;
  data _null_;

    file wordsys;

    put '[EditGoto.Destination="t"]';

    put '[TableSelectTable]';

  run;

  %* Wrap a Word Bookmark TABLE around the selection.               *;
  data _null_;

    file wordsys;

    put '[EditBookmark.Name="table",.Add]';

  run;

  %* Then define a DDE-triplet filename pointing to the TABLE book- *;
  %* mark.                                                          *;
  filename wordtabl dde 'winword|document with a table!table' notab;

  %* Read the lot into a data set for further processing ...        *;
  data table_from_document;

    length
      col1 $ 50
      col2 $ 15
      col3 $ 20
      ;

    infile wordtabl dsd missover dlm='09'x;

    input
      col1

      col2

      col3

      ;

  run;

  proc print;;

  %* Close the document, clear the filename.                        *;
  data _null_;

    file wordsys;

    put '[FileClose 2]';

  run;

